Le web de Dominique Guebey – IBM AS/400 iSeries

Page web  : http://www.dg77.net/tekno/as400/as400sav.htm

Aller au principal/Skip to main content
   D o m i n i q u e   G u e b e y    J u n g l e      IBM AS/400 iSeries

Méthode de sauvegarde et restauration d’un AS400

Sommaire :

Une méthode parmi d’autres

Les différentes catégories de données :

A : sauvegarde EXCLUSIVE, à faire en mode restreint
  1. OS
  2. Microcode
  3. Logiciels IBM sous licence
  4. Dossiers
  5. IFS
B : Sauvegarde périodique
Bibliothèques logiciels ne nécessitant pas une sauvegarde quotidienne et pouvant être copiées en cours de journée sans gêne.
C : Sauvegarde quotidienne
Bibliothèques des données et autres – IFS…
Données de sécurité et de configuration.
Bibliothèques non sauvegardées
Bibliothèques contenant elles-mêmes des sauvegardes,
Bibliothèques de travail, temporaires ou de restauration

CL de sauvegarde système

/*                                                                   */
/*                 SAUVEGARDE SYSTEME EVOLUEE                        */
/*                 --------------------------                        */
/*                                                                   */
/* Auteur    : Dominique Guebey                                      */
/* Version 1 : 13 nov 2001                                           */
/* Version 2 : 17 fev 2006                                           */
/*                                                                   */
/* Cette procedure :                                                 */
/* - met le systeme en mode restreint (ENDSYS),                      */
/* - initialise la bande (INZTAP),                                   */
/* - sauvegarde microcode, QSYS et donnees de configuration et de    */
/*   securite (SAVSYS),                                              */
/* - sauvegarde les logiciels sous licence, QGPL, QUSRSYS, et les    */
/*   bibliotheques utilisateurs (SAVLIB *NONSYS) a l'exception de    */
/*   celles qu'on ne veut pas (OMITLIB) :                            */
/*   - bibliotheques sauvegardees sur d'autres sauvegardes,          */
/*   - bibliotheques qu'on n'a pas besoin de sauvegarder,            */
/* - sauvegarde les dossiers (SAVDLO),                               */
/* - sauvegarde l'IFS (SAV),                                         */
/* - facultativement : lance un RCLSTG et un RCLDLO,                 */
/* - redemarre le systeme (PWRDWNSYS RESTART(*YES))                  */
                                                                       
PGM (&HRE &LAB &DEV &RCL)                                              
DCL &HRE *CHAR 006        /* Heure de demarrage (defaut : immediat)  */
DCL &LAB *CHAR 006        /* Label de la cartouche (defaut : IBMIRD) */
DCL &DEV *CHAR 010        /* Unite (defaut : TAP01)                  */
DCL &RCL *CHAR 001        /* Option : si "R", RCLSTG et RCLDLO       */
                                                                       
DCL &JOB *CHAR 010                                                     
DCL &CNS *CHAR 010                                                     
DCL &TYP *CHAR 001                                                     
DCL &WTP *CHAR 032                                                     
                                                                       
RTVJOBA TYPE(&TYP)                        /* 1=interactif            */
IF (&TYP *EQ '0') RETURN                  /* 0=batch (interdit)      */
                                                                       
RTVJOBA JOB(&JOB)                                                      
RTVSYSVAL QCONSOLE &CNS                                                
IF (&CNS *NE &JOB) (DO)                   /* Faut etre a la console  */
   SNDBRKMSG ('Attention, cet ecran ' !! &JOB !! ' n est pas la +      
             console ' !! &CNS) TOMSGQ(&JOB)                           
   MONMSG CPF0000                                                      
   RETURN                                                              
   ENDDO                                                               
                                                                       
IF (&HRE *EQ ' ') GOTO (SUITE)            /* Demarrage immediat      */
DLYJOB RSMTIME(&HRE)                      /* Temporisation           */
MONMSG CPF0000 EXEC(DO)                                                
   SNDBRKMSG ('Probleme dans l heure : ' !! &HRE) TOMSGQ(&JOB)         
   MONMSG CPF0000                                                      
   RETURN                                                              
   ENDDO                                                               
                                                                       
SUITE:                                                                 
IF (&DEV *EQ ' ') CHGVAR &DEV 'TAP01     '                             
VRYCFG &DEV *DEV *ON                                                   
MONMSG CPF0000                                                         
IF (&LAB *EQ ' ') CHGVAR &LAB 'IBMIRD'                                 
INZTAP &DEV (&LAB) CHECK(*NO)             /* Initialise le support   */
MONMSG CPF0000 EXEC(DO)                                                
   SNDBRKMSG ('Probleme avec la bande ou l unite de sauvegarde, ' +    
             !! &DEV !! ' ou avec le label ' !! &LAB) +                
             TOMSGQ(&JOB)                                              
   MONMSG CPF0000                                                      
   RETURN                                 /* Si probleme, abandon    */
   ENDDO                                                               
                                                                       
ENDSYS (*IMMED)                           /* Mode restreint          */
MONMSG CPF0000 EXEC(DO)                                                
   SNDBRKMSG ('Impossible de mettre le systeme en mode restreint') +   
             TOMSGQ(&JOB)                                              
   MONMSG CPF0000                                                      
   RETURN                                 /* Si probleme, abandon    */
   ENDDO                                                               
DLYJOB DLY(180)                           /* Temporise 3mn           */
                                                                       
DEBUT:                                                                 
SAVSYS &DEV VOL(*MOUNTED) ENDOPT(*LEAVE)  /* Microcode + QSYS        */
MONMSG MSGID(CPF3785) EXEC(DO)            /* Pas encore mode restrein*/
   DLYJOB DLY(060)                        /* Attente d une minute    */
   GOTO DEBUT                             /* Boucle                  */
   ENDDO                                                               
MONMSG CPF0000                                                         
                                                                       
/* Bibliotheques utilisateurs, QGPL, QUSRSYS, logiciels sous licence */
SAVLIB *NONSYS &DEV VOL(*MOUNTED) OMITLIB(                            +
       CORBEILLE DGUEBEY GENERAL INFOU INSTAL LAFAXXX POLLUX          +
       POUKOF SAUVE* STAT TRANS UCCHAU*                               +
       ) ENDOPT(*LEAVE) TGTRLS(*CURRENT)                               
MONMSG CPF0000                                                         
                                                                       
SAVDLO *ALL &DEV ENDOPT(*LEAVE)           /* Dossiers et distrib.    */
MONMSG CPF0000                                                         
                                                                       
CHGVAR &WTP ('/QSYS.LIB/' *TCAT &DEV *TCAT '.DEVD')                
SAV DEV(&WTP) OBJ(('/*') +                                             
       ('/QSYS.LIB' *OMIT)                 +                           
       ('/QDLS'     *OMIT))               /* Le reste de l'IFS       */
MONMSG CPF0000                                                         
                                                                       
IF (&RCL *NE 'R') GOTO (RES)              /* Suite facultative       */
                                                                       
ENDCMTCTL                                 /* Arrete le controle de   */
MONMSG CPF0000                            /* validation              */
RCLSTG                                    /* Nettoyage disques       */
MONMSG CPF0000                            /* Attention : TRES LONG   */
                                                                       
RCLDLO *ALL                               /* Reorg dossiers          */
MONMSG CPF0000                                                         
                                                                       
RES:                                                                   
DSPTAP &DEV OUTPUT(*PRINT)                /* Liste la bande          */
MONMSG CPF0000                                                         
PWRDWNSYS *IMMED RESTART(*YES)            /* Redemarage du systeme   */
ENDPGM

Le prompt de lancement

CMD PROMPT('SAUVEGARDE SYSTEME')

PARM KWD(HRE) TYPE(*CHAR) LEN(6)                                   +
     PROMPT('Heure de démarrage')
PARM KWD(LAB) TYPE(*CHAR) LEN(6)                                   +
     PROMPT('Label bande (défaut : IBMIRD)')
PARM KWD(DEV) TYPE(*CHAR) LEN(10)                                  +
     PROMPT('UNITE (défaut : TAP01)')
PARM KWD(RCL) TYPE(*CHAR) LEN(1)                                   +
     PROMPT('"R"=REORG (RCLSTG/RCLDLO)')

Restauration intégrale et manuelle

En cas de catastrophe…

recharger microcode et bibliothèque QSYS
Cette tâche incombe normalement au technicien de maintenance matériel.
Utiliser la bande A « SAVSYS » (unité d’IPL : lecteur 4 Go).
La bande étant montée, lancer un IPL « D » (voir note « arrêt-redémarrage du système », démarrage au panel).
Restaurer les logiciels sous licences et diverses bibliothèques :
Toujours sur la bande « SAVSYS »
Ouvrir une session.
Se mettre en mode restreint :  ENDSYS *IMMED  (cela demande quelques minutes : voir les messages-système).
Entrer la commande :  RSTLIB NONSYS DEV(TAP01) ENDOPT(*LEAVE) 
Restaurer les dossiers :
Toujours sur la bande « SAVSYS »
Entrer la commande :  RSTDLO *ALL DEV(TAP01) 
Restaurer les logiciels utilisateurs :
Sur la bande B « SAVNMH » (unité 26 Go).
Entrer la commande :  RSTLIB *ALLUSR DEV(TAP01) 
Restaurer les données :
Sur la dernière bande sauvegarde quotidienne (C).
Restaurer les bibliothèques de données ; entrer, dans l’ordre :

Cet exemple concerne un système muni d’une deuxième unité de cartouche (TAP02) sur laquelle est exécutée la sauvegarde quotidienne. Cela permet une sauvegarde système (sur TAP01) sans intervention humaine le week-end. Ce CL est à lancer en direct à la Console.

        RSTLIB TRAFIC400 DEV(TAP02) ENDOPT(*LEAVE)
        etc.
Restaurer la configuration :
 RSTCFG *ALL DEV(TAP02) ENDOPT(*LEAVE) ALWOBJDIF(*ALL) 
Restaurer les données de sécurité :
 RSTUSRPRF *ALL DEV(TAP02) ENDOPT(*LEAVE) ALWOBJDIF(*ALL) 
 RSTAUT ALL ENDOPT(LEAVE) 
Arrêter/Redémarrer le système (nécessaire pour sortir du mode restreint).
Restauration du système de fichiers intégré :
 RST DEV('/QSYS.LIB/TAP02.DEVD') OBJ(('*')) 

(Re)installation (plus récent)

Complément issu d’une expérience plus récente que ce qui précède

** IPL D-M avec la bande SAVSYS

1h33 ** Affichage DST à la console : 
            [1] Installation du microcode sous licence
            (** "Attendez l'écran suivant ou appuyez sur F16 pour obtenir…" :
            Ne pas toucher au clavier) 
1h37 ** "Installation du microcode sous licence"
            "Disque sur lequel…"
            Choisir :
            [2] Installer le microcode sous licence et initialiser le système
            F10 pour confirmer
1h39 ** L'initialisation du disque commence ("temps estimé : 36mn")
1h51 ** Apparition du graphe d'installation du microcode sous licence
2h08 ** IPL automatique
2h15 ** "Disk configuration - Attention Report"
            [5] Detailed report
  
          F3 puis [3] pour DST puis :
	4 Work with disk units
            1 Work with disk configuration
            3 Work with ASP Configuration
            3 Add units to ASPs
        ** Demande de changer le mot de passe DSP
            Attention : il est CASE SENSITIVE
2h25 ** Ajout des disques à l'ASP1
           Une fois les disques ajoutés, réaffichage de l'écran Problem Report, 
           F10 pour continuer
2h40 ** Configuration et démarrage du mirroring : 
        ___ 1 On the Work with Disk Configuration screen, select 4, Work with Mirrored Protection.  
        ___ 2 On the Work with Mirrored Protection screen, select 2, Start Mirrored Protection.
        ___ 3 Select an ASP by typing 1 next to it. Press the Enter key to start mirrored protection.
        ___ 4 On the Confirm Continuation screen, press the Enter key.
        ___ 5 On the Confirm Start Mirrored Protection screen, press the Enter key. 
        ___ 6 The Function Status screen displays the completion status of the St
art Mirrored Protection \ request. 
        ___ 7 The Start mirroring completed successfully message appears on the Disk Configuration Information Report screen.
        ___ 8 Press the Enter key to continue.
	IPL
2h55 ** "IPL or install system"
            [2] Install the Operating system
            "Confirm" Enter 
            1 (tape/bande)
            Dispositif de langue (2928)
            Confirmer
            La synchronisation du mirroring commende (48mn)
3h47 ** suite IPL
	Les differentes etapes apparaissent sous forme de graphe

Message ID . . : CPI2070 OS/400 Installation Status 

+-------------------------------------------------------------+ 
Stage 1 |xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx | 
+-------------------------------------------------------------+ 
0 20 40 60 80 100 

Installation Objects 
Stage Completed Restored 

1 Creating needed profiles and libraries . .: x 
2 Restoring programs to library QSYS . . . .: x 09 
3 Restoring language obje
cts to library QSYS: x 03 
4 Updating program table . . . . . . . . . .: x 
5 Installing database files . . . . . . . . : x 
6 Completing OS/400 installation . . . . . .: 


5h10 ** Ouverture d'une session console, suite IPL manuel
	- entrer date heure
            - changer le psw QSECOFR
        GO RESTORE
        option 21 (restauration des données système et utilisateurs)
5h45 ** Affichages (exemple de message)
        "47 bibliotheques sur 105 traitees. 19 objets restaures dans QICU"
7h30 ** Restauration de l'IFS (18042 objets)
9h30 ** restauration des droits (RSTAUT), STRSBSD etc.

REMETTRE le SYSTEME en IPL NORMAL
REDEMARRER L'AS400
RESTORER LES DONNEES

REFERENCES :
http://www-912.ibm.com/s_dir/slkbase.NSF/4636aef020ecf0688625680b00020388/8436551a53371b4e86256ac600605917?OpenDocument
http://as400bks.rochester.ibm.com/iseries/v5r2/ic2924/books/c4151206.pdf